閑人

アクセスカウンタ

zoom RSS LTspice TL431 モデル作成

<<   作成日時 : 2016/11/23 18:20   >>

ブログ気持玉 0 / トラックバック 0 / コメント 0

LTspiceで、TL431のモデルを2種類作っています。
画像

1つ目、ONセミの電圧源を使ったモデル 回路で、とりあえず定電圧電源が必要な場合に使います。

*This is the model from our spice lib.(http://www.onsemi.jp/)
.SUBCKT TL431ONSEMI KA AN REF
* K A FDBK
*V1 1 AN 2.495 ; used for fixed reference, replaced with EB1 Limiter
EB1 1 AN Value = { IF ( V(KA,AN)> 2.495, 2.495, V(KA,AN) ) }
R1 AN 2 15.6
C1 2 AN .5U
R2 2 3 100
C2 3 4 .08U
R3 4 AN 10
G2 AN 8 3 AN 1.73
D1 5 8 DI
D2 KA 8 DI
V4 5 AN 2
G1 AN 2 1 REF 0.11
*
.MODEL DI D(IS=13.5N RS=25M N=1.59 CJO=45P VJ=.75 M=.302 TT=50.4N BV=34V IBV=1MA)
*
.ENDS TL431ONSEMI



2つ目、昔のデータシートの回路図から、SPICEのネットリストをExcelで作成する方法です。SPICE2の頃は、回路図エディター等は無かったので、専用のネットリスト作成環境を作っていました。例えば、Excelに、部品毎のパラメータを入力する欄を決めて、部品端子の名前の付け方を決めて、最初に、部品番号、部品名称を入れてから、ネット名称を、順番に入れて、回路図に赤線で消し込んで行きます。Excelから、TAB区切りの出力ファイルを作成して、これを、テキストエディタで、編集します。例えば

*TL431TI LTSPICE model for LTspiceXVII
*USE TL1009 SYMBOL AND EDIT Attribute and Save As TL431TI.asy
*Equivalent Schematic form TI's Datasheet slvs543o.pdf Page 19 Figure 23
*
.SUBCKT TL431TI CATHODE ANODE REF
*
Q1 CATHODE REF Q1E 0 NPN1
Q2 N003 N003 REF 0 NPN1
Q3 N010 N010 ANODE 0 NPN1
Q4 N011 N010 N013 0 NPN1
Q5 N004 N004 N001 0 PNP1
Q6 N003 N004 N002 0 PNP1
Q7 N004 Q1E N007 0 NPN1
Q8 N009 N011 ANODE 0 NPN1
Q9 N003 N012 ANODE 0 NPN1
Q10 CATHODE N003 N005 0 NPN1
Q11 CATHODE N006 ANODE 0 NPN1
*
D1 ANODE N003 DIODE
D2 ANODE CATHODE DIODE
*
R1 Q1E N008 3.28k
R2 N008 N010 2.4k
R3 N008 N011 7.2k
R4 N013 ANODE 800
R5 N007 N009 4k
R6 CATHODE N001 800
R7 CATHODE N002 800
R8 N012 N010 1k
R9 N006 N005 150
R10 N006 ANODE 10k
*
C1 N009 N011 20p
C2 CATHODE N003 20p
*
*Model is irresponsible.
*
.model PNP1 PNP(bf=150)
.model NPN1 NPN(IS=1e-14 bf=250 tf=2n cjc=1p is=5e-18 NF=1.07)
.model DIODE D(rs=1 cjo=2p)
*
.ENDS TL431TI

シンボルのピン番号と、端子信号名の並びは、良く確認してください。
LTspiceXVIIのLT1009のシンボルを書換えて使っています。
トランジスタBJTのデフォルトだと、REFの電圧が2.2V程度になってしまいます。ある程度Hfe(BF)を大きくしてあります。だいたい、2.495V近辺になります。

これを、シミュレーションしてみると
画像

ちょっとした違いですが、トランジスタを使ったモデルでは、負荷容量の変化による発振の確認もできます。何に使うかで、SPICEのモデル選択も違います。
私が、初心者の内は、回路図をそのままSPICEで記述して、シミュレーションしていました。でも、モデルの中身を知らないと、電源やオペアンプ等の設計で必要な、位相マージンや補償回路の設計が出来ない事を知りませんでした。こんな経験から、できる限り実物を測定して、SPICEモデルを作るようにしています。

今回、LTspiceXVIIを使って、UNICODEで日本語が使えるようになったことを確認できました。また、回路図を書いて、SPICEの記述で表示した後、専用のエディターが使える事もわかりました。LTspice自体が階層構造で回路が書けるし、これをサブサーキットにすることもできるので、変換する手間が余分にかかり、普通の人は使わないのですが。
画像

試行錯誤中のSPICE LISTです。「ねがてぃぶろぐ LTspiceでTL431」のページは大変参考になりました。断りも無く参照させて頂きました。gomisai様ありがとうございます。

まだ、モデルの移行が終わりません。本を読みながら、LTspiceをいじってみると、シンボルのパラメータにある、Value変数を使うと、同じシンボルは、1つのサブサーキットライブラリにまとめられるようです。また、ライブラリのPATHも、自由に追加指定できるようなので、勉強中です。
でも、纏めてしまうと、シンボルファイルが参照できなくなります。

LTspiceIVは、もう更新しないようです。MAC版はどうするのでしょうか?

テーマ

注目テーマ 一覧


月別リンク

ブログ気持玉

クリックして気持ちを伝えよう!
ログインしてクリックすれば、自分のブログへのリンクが付きます。
→ログインへ

トラックバック(0件)

タイトル (本文) ブログ名/日時

トラックバック用URL help


自分のブログにトラックバック記事作成(会員用) help

タイトル
本 文

コメント(0件)

内 容 ニックネーム/日時

コメントする help

ニックネーム
本 文
LTspice TL431 モデル作成 閑人/BIGLOBEウェブリブログ
文字サイズ:       閉じる